[Terraform] 기본 사용법#4 (local 지역값, 출력 output, 반복문)

💡cloudNet@ 팀의 가시다 님이 진행하는 Terraform 101 Study 4기 2주차 내용으로,
[테라폼으로 시작하는 IaC] 도서를 참조하였습니다. 감사합니다..

 

1. local (지역값)

코드 내에서 사용자가 지정한 값 또는 속성 값을 가공해 참조 가능한 local (지역 값) 은 외부에서 입력되지 않고, 코드 내에서만 가공되어 동작하는 값을 선언한다.

‘local’은 입력 변수와 달리 선언된 모듈 내에서만 접근 가능하고, 변수처럼 실행 시에 입력받을 수 없다.

 

로컬은 사용자가 테라폼 코드를 구현할 때 값이나 표현식을 반복적으로 사용할 수 있는 편의를 제공한다. 하지만 여러 곳에서 자주 사용되는 경우 실제 값에 대한 추적이 어려워지므로 유지 관리 측면에서 부담이 발생할 수 있다. 주의할 것!!

 

1.1 local 선언

로컬이 선언되는 블록은 locals로 시작한다. 선언되는 인수에 표현되는 값은 상수만이 아닌 리소스의 속성, 변수의 값들도 조합해 정의할 수 있다.

동일한 tf 파일 내에서 여러번 선언하는 것도 가능하고 여러 파일에 걸쳐 만드는 것도 가능하다.

 

다만 locals에 선언한 로컬 변수 이름은 전체 루트 모듈 내에서 유일해야 한다.

 

정의되는 속성 값은 지정된 값의 형태에 따라 다양한 유형으로 정의할 수 있다.

 

local 값 선언 방식 예제 코드

variable "prefix" {
  default = "hello"
}

**locals** {
  name    = "terraform"
  **content** = "${var.prefix} ${local.name}"
  my_info = {
    age    = 20
    region = "KR"
  }
  my_nums = [1, 2, 3, 4, 5]
}

**locals** {
  **content** = "content2" # 중복 선언
}

 

해당 코드를 실행해보니, 다음과 같이 오류가 발생한다. locals에 content가 중복 선언되었기 때문이다.

사진-0

 

1.2 local 참조

선언된 local 값은 local.<이름>으로 참조할 수 있다. 테라폼 구성 파일을 여러 개 생성해 작업하는 경우 서로 다른 파일에 선언되어 있더라도 다른 파일에서 참조할 수 있다.

 

dev.tf 와 ops.tf 파일을 작성하여 plan을 실행해 local 참조를 테스트해보겠다.

# dev.tf
variable "prefix" {
  default = "hello"
}

locals {
  name    = "terraform"
}

resource "local_file" "abc" {
  content  = local.content
  filename = "${path.module}/abc.txt"
}

# ops.tf
locals {
  content = "${var.prefix} ${local.name}"
}

 

dev.tf 파일의 content 내용 값으로 local.content를 참조한다. 해당 값은 다른 테라폼 구성 파일에 있지만 실행시 하나의 구성 파일처럼 정상적으로 생성되는 것을 확인할 수 있다.

사진-1

 

해당 테스트로 서로 다른 구성 파일에서도 로컬 값을 참조할 수 있다는 것을 확인했으나, 관리적인 측면에서 보면 서로 참조하는 로컬값이 많아지면 파편화되어 유지 보수가 어려워 질 수 있으니 유의해야한다..!

 

local은 어떻게 사용하면 좋을까?

많이 사용할 수록 관리가 어려울 것 같은데, 어떻게 사용하는 것이 좋을까?

일단 가장 큰 특징인 외부에서 입력되지 않고 코드 내로만 동작하며 실행시에 입력할 수도 없다는 점으로 중요한 리소스 즉, 자주 변하지 않거나 잘못 입력하는 것을 방지하는 목적으로 사용하는 것이 바람직해 보인다.

 

혹은 인프라 리소스간의 의존성이라고 해야할까? local의 참조할 수 있는 특징을 이용해서 다른 리소스들과 연결이 많이 되는 중요한 대상의 경우 local로 관리하게 되면 관리가 수월해지지 않을까 싶다.

(경험이 많이 없어 단순히 생각해봤습니다. 다른분들은 어떻게 사용하는지 알려주시면 감사~^^)

 

1.3 local 실습 AWS IAM User 생성 [스터디 제공]

다음과 같이 파일 내용을 작성하고 apply를 진행한다.

# iamuser.tf
provider "aws" {
  region = "ap-northeast-2"
}

**locals** {
  **name** = "mytest"
  **team** = {
    group = "dev"
  }
}

resource "aws_iam_user" "**myiamuser1**" {
  name = "${local.name}1"
  tags = local.team
}

resource "aws_iam_user" "**myiamuser2**" {
  name = "${local.name}2"
  tags = local.team
}

사진-2

사진-3

사진-4

 

2. output (출력)

출력 값은 주로 테라폼 코드의 프로비저닝 수행 후의 결과 속성 값을 확인하는 용도로 사용된다. 또한 프로그래밍 언어에서 코드 내 요소 간에 제한된 노출을 지원하듯, 테라폼 모듈 간, 워크스페이스 간 데이터 접근 요소로도 활용할 수 있다.

 

예를 들면 자바의 *getter와 비슷한 역할이다. 출력 값의 용도는 다음과 같다.

• 루트 모듈에서 사용자가 확인하고자 하는 특정 속성 출력
• 자식 모듈의 특정 값을 정의하고 루트 모듈에서 결과를 참조
• 서로 다른 루트 모듈의 결과를 원격으로 읽기 위한 접근 요소

출력 값을 작성하면 단순한 디버깅을 넘어 속성 값을 노출하고 접근할 수 있어 다른 작업자 및 팀 협업에 유용하다.

• getter : java에서 private를 관리하는 메서드. private할때 다른 클래스에서 접근하려면 해당 클래스 안의 메서드를 통해서만 가능한데, 그 관리하는 메서드를 Getter(외부로 리턴), Setter(내부로 반환) 라고 부른다.

 

2.1 output 선언

모듈 내에서 생성되는 속성 값들은 output 블록에 정의된다.

**output** "instance_ip_addr" {
  value = "http://${aws_instance.server.private_ip}"
}

출력되는 값은 value의 값이며 테라폼이 제공하는 조합과 프로그래밍적인 기능들에 의해 원하는 값을 출력할 수 있다.

 

주의할 점은 output 결과에서 리소스 생성 후 결정되는 속성값에 대해서는 프로비저닝이 완료되어야 최종적으로 결과를 확인할 수 있다.(즉, plan 단계에서는 적용될 값을 출력하지 않는다는 것.)

 

변수 정의 시 사용 가능한 메타인수는 다음과 같다.

• description : 출력 값 설정
• sensitive : 민감한 출력 값임을 알리고 테라폼의 출력문에서 값 노출을 제한
• depends_on : value에 담길 값이 특정 구성에 종속성이 있는 경우 생성되는 순서를 임의로 조정
• precondition : 출력 전에 지정된 조건을 검증

 

sensitive의 경우 값이 출력되지 않으므로 디버깅 목적보단 값을 노출하지 않고 다른 모듈에서 참조하기 위한 목적으로 활용된다!

 

2.2 output 활용 & abspath 함수

output 블록 동작 확인을 위해 다음과 같이 파일을 작성한다.

resource "local_file" "abc" {
  content  = "abc123"
  filename = "${path.module}/abc.txt"
}

output "file_id" {
  value = local_file.abc.id
}

output "file_abspath" {
  value = **abspath**(local_file.abc.filename)
}

• abspath : 파일 시스템 경로를 포함하는 문자열을 가져와 절대 경로로 반환하는 함수 https://developer.hashicorp.com/terraform/language/functions/abspath

abspath - Functions - Configuration Language | Terraform | HashiCorp Developer

 

plan 실행 시 이미 정해진 속성(file_abspath)은 출력 결과를 예측하지만, 아직 생성되지 않은 file_id 값은 결과 예측을 할 수 없다. apply를 진행해야 생성된 결과를 확인할 수 있다.

사진-5

사진-6

 

 

3. 반복문

list 형태의 값 목록이다 Key-Value 형태의 문자열 집한인 데이터가 있는 경우 동일한 내용에 대해 테라폼 구성 정의를 반복적으로 하지 않고 관리할 수 있다.

 

3.1 count

리소스 또는 모듈 블록에 count 값이 정수인 인수가 포함된 경우 선언된 정수 값만큼 리소스나 모듈을 생성하게 된다. count에서 생성되는 참조값은 count.index이며, 반복하는 경우 0부터 1씩 증가해 인덱스가 부여된다.

 

count 값이 있는 반복문 동작 확인을 위해 다음과 같이 파일를 작성한다.

**resource** "local_file" "abc" {
  **count    = 5**
  content  = "abc"
  filename = "${path.module}/**abc.txt**"
}

output "filecontent" {
  value = local_file.abc.*.content
}

output "fileid" {
  value = local_file.abc.*.id
}

output "filename" {
  value = local_file.abc.*.filename
}

 

위 파일을 apply로 실행하니 count =5로 총 5개의 파일이 생성되어야 하나 파일명이 동일하여 하나의 파일만이 생성되었다.

사진-7

count를 사용하는 경우 반복되는 정의로 인해 문제되는 값이 있는지 주의해야 한다!!

 

 

main.tf를 다음과 같이 수정한 후 apply를 진행하였다. 이번엔 다수의 파일이 생성되는 것을 확인할 수 있다.

resource "local_file" "abc" {
  count    = 5
  content  = "This is filename abc**${count.index}**.txt"
  filename = **"${path.module}/**abc**${count.index}.txt"**
}

output "fileid" {
  value = local_file.abc.*.id
}

output "filename" {
  value = local_file.abc.*.filename
}

output "filecontent" {
  value = local_file.abc.*.content
}

사진-8

 

때로는 여러 리소스나 모듈의 count로 지정되는 수량이 동일해야 하는 상황이 있다. 이 경우 count에 부여되는 정수 값을 외부 변수에 식별되도록 구성할 수 있다.

 

list 형태에 배열을 활용하여 반복문 동작 구성을 진행하였다.

variable "names" {
  type    = list(string)
  default = ["a", "b", "c"]
}

resource "local_file" "abc" {
  count   = length(var.names)
  content = "abc"
  # 변수 인덱스에 직접 접근
  filename = "${path.module}/abc-${var.names[count.index]}.txt"
}

resource "local_file" "def" {
  count   = length(var.names)
  content = local_file.abc[count.index].content
  # element function 활용
  filename = "${path.module}/def-${element(var.names, count.index)}.txt"
}

 

local_file.abc와 local_file.def는 var.names에 선언되는 값에 영향을 받아 동일한 개수만큼 생성하게 된다. local_file.def의 경우 local_abc와 개수가 같아야 content에 선언되는 인수 값에 오류가 없을 것이므로 서로 참조되는 리소스와 모듈의 반복정의에 대한 공통의 영향을 주는 변수로 관리할 수 있다.

사진-9

 

count로 생성되는 리소스의 경우 <리소스 타입>, <이름>,[<인덱스 번호>],

모듈의 경우 module,<모듈 이름>,[<인덱스 번호>] 로 해당 리소스의 값을 참조한다.

 

• 단, 모듈 내에 count 적용이 불가능한 선언이 있으므로 주의해야 한다!!

예를 들어 provider 블록 선언부가 포함되어 있는 경우에는 count 적용이 불가능하다. 또한 외부 변수가 list 타입인 경우 중간에 값이 삭제되면 인덱스가 줄어들어 의도했던 중간 값에 대한 리소스만 삭제되는 것이 아니라 이후에 정의된 리소스들도 삭제되고 재생성된다.

 

해당 내용은 반복문 실습과 다음 포스팅할 cloudnet 스터디 악분님이 제공해주신 스터디에서 한번 확인해보도록 하겠다.

 

3.2 반복문 실습

실습1. IAM 사용자 3명 생성

테라폼은 언어에 내장된 절차 논리가 없어 범용 프로그래밍 언어의 for 와 같은 동작을 할 수 없다.

다음과 같이 count에 정수를 지정하여 수행한다.

# 1_iam_user_test.tf
provider "aws" {
  region = "ap-northeast-2"
}

resource "aws_iam_user" "myiam" {
  **count = 3**
  name  = "myuser.**${count.index}**"
}

사진-10

 

실습2. count 입력 변수를 통해 IAM 사용자 생성

count와 배열 조 구문과 length 함수를 이용하여 여러 사용자를 생성할 수 있다.

이전 1_iam_user_test.tf 파일 내용을 수정하고, 2_variable.tf 파일을 생성한다.

# 1_iam_user_test.tf
provider "aws" {
  region = "ap-northeast-2"
}

resource "aws_iam_user" "myiam" {
  **count = length(var.user_names)
  name  = var.user_names[count.index]**
}

# 2_variable.tf
variable "user_names" {
  description = "Create IAM users with these names"
  type        = list(string)
  default     = ["chanwoo", "devops", "study"]
}

사진-11

chanwoo, devops, study 3개의 IAM 계정이 생성된다.

 

실습 3. count 제약사항 (인라인 블록 반복 X)

count의 경우 배열 중간 값을 변경하게 되면 의도하지 않은 결과가 발생할 수 있다.

이는 중간에 배열이 삭제되게 되면 모든 항목이 앞으로 당겨지게 되는데, 테라폼은 인덱스 번호를 리소스 식별자로 판단하기 때문에 인덱스 1에서 계정 삭제, 인덱스 2에서 계정 생성 등으로 보게 된다.

즉, count 사용 시 목록 중간 항목을 제거하면 테라폼은 해당 항목 뒤 모든 리소스를 제거한 후 다시 생성하게 된다.

 

다음과 같이 IAM 항목을 수정하고 plan을 진행하겠다.

# 2_variable.tf
variable "user_names" {
  description = "Create IAM users with these names"
  type        = list(string)
  # 중간 devops 값을 제거
  # default     = ["chanwoo", "devops", "study"]
  default     = ["chanwoo", "study"]
}

사진-12